FF5 iOS - strange PNG format

[puggsoy]

Here's a QuickBMS script I made to extract the .bin files:

Code:

# Final Fantasy 5 (iOS) .bin format
#
# Written by puggsoy
# script for QuickBMS http://quickbms.aluigi.org

open FDSE "data0.bin" 1

idstring FFDL
idstring 1 FFDL

get FILENUM basename
string FILENUM | data

goto 8 1
get NAMESPOS long 1

goto 0x14 1
savepos POS 1

for POS = POS < NAMESPOS
    get NAMEOFF long 1
    math NAMEOFF += NAMESPOS
    get SIZE long 1
    get SIZE2 long 1
    get NUM long 1
    get OFFSET long 1
    get DUMMY long 1
    
    if NUM == FILENUM
        savepos TEMP 1
        goto NAMEOFF 1
        get NMSZ byte 1
        getdstring NAME NMSZ 1
        goto TEMP 1
        
        goto OFFSET
        getdstring TYPE 3
        
        if TYPE == "INP"
            math OFFSET += 4
            math SIZE -= 4
        elif TYPE == "ICP"
            string NAME += ".icp"
        endif
        
        log NAME OFFSET SIZE
    endif
    
    savepos POS 1
next

Keep in mind that for this to work you MUST have the data0.bin in the same folder of whatever .bins you're extracting, since that holds all the offsets, sizes, and names. Otherwise the script will just fail.

The script will properly extract all the unencrypted PNG files (it'll just remove the INP header) so those will be directly viewable. However all the encrypted ones will have an ".icp" extension added onto the end. You'll also see ".dat" files with this on the end, those are also just encrypted PNGs so I don't know why they originally have a ".dat" extension. In any case, I'll try make a converter soon that should be able to convert any ".icp" file into a usable PNG

P.D.: Would it be possible to use the same procedure with FF Dimensions? It's also encrypted in .BIN files like FF5.

No idea, you can upload some (or all) of them and I can take a look.